c ----------------------------------------------------------------
c ScrPrep.cct: Scripture Text Preparation
c ----------------------------------------------------------------
c Prepares scripture for interlinearization or adaptation by
c adding a \t marker after every appropriate scripture marker.
c For more information, search for ScrPrep.cct in Shoebox Help.
c ----------------------------------------------------------------
c Revision history
c                   11 Jul 2000 added revision history
c 1.1   A Buseman   25 Oct 1999 output \c 0 first
c 1.0   A Buseman   25 Jun 1996
c ----------------------------------------------------------------

begin > store(vnum) '1234567890' endstore c verse numbers
        store(vpunc) ',-' endstore c verse number punctuation
        '\c 0' nl   c default marker for first record

c ------------------------------------------
group(main)

'\' > dup use(sfmark)   

c ------------------------------------------
group(sfmark)   c pass by a standard format marker, and add \t

nl '\' > dup    c stay here if another marker is coming

' ' any(vnum) > next c pick up first number with its space
any(vpunc) > next
any(vnum) > dup   c stay here through numbers and number punc

' ' > next
nl > nl '\t ' use(main)   c add text mark after every sf mark